Basic у Python

Зміст

# Виклик скриптів на Python з Basic

З макросів LibreOffice Basic можна викликати скрипти на Python, що дозволяє:

- ідентифікацію за ComputerName або визначення OSName,

- обійти за допомогою Python обмеження на розмір файла 2 ГБ для функції Basic FileLen() і функції API com.sun.star.ucb.SimpleFileAccess. getSize(),

- нормалізувати com.sun.star.util.PathSettings,

- і багато іншого.

Розсудливе застосування LibreOffice Basic та властивостей Прикладний програмний інтерфейс (API) рекомендується перед виконанням міжмовних запитів з Basic до Python, до JavaScript чи будь-якого іншого скриптового рушія.

## Отримання сценаріїв Python

Сценарії Python можуть бути локальними, розділеними або вкладеними в документи. Для їх виконання необхідно передати LibreOffice Basic інформацію про їхнє розташування. Після отримання посилання на об’єкти UNO, сумісні з інтерфейсом com.sun.star.script.provider.XScript, сценарії Python можна виконувати:

             Option Explicit

             Public Function GetPythonScript(macro As String, _
                     Optional location As String) As com.sun.star.script.provider.Xscript
                 '“” Захоплення об’єкта сценарію Python перед виконанням
                 ' Аргументи:
                 '    макрос   : як "library/module.py$macro" або "module.py$macro"
                 '    розташування: як "document" (вкладений), "share" (поширюваний), "user" (локальний) або ENUM (перелік)
                 ' Результат:
                 '    посилання на службу UNO com.sun.star.script.provider.XScript'''
                 If IsMissing(location) Then location = "user"
                 Dim mspf As Object ' com.sun.star.script.provider.MasterScriptProviderFactory
                 Dim sp As Object ' сумісний з com.sun.star.script.provider.XScriptProvider
                 Dim uri As String
                 If location="document" Then
                     sp = ThisComponent.getScriptProvider()
                 Else
                     mspf = CreateUnoService("com.sun.star.script.provider.MasterScriptProviderFactory")
                     sp = mspf.createScriptProvider("")
                 End If
                 uri = "vnd.sun.star.script:"& macro &"?language=Python&location="& location
                 GetPythonScript = sp.getScript(uri)
             End Function ' GetPythonScript

## Виконання сценаріїв Python

The LibreOffice Application Programming Interface (API) Scripting Framework supports inter-language script execution between Python and Basic, or other supported programming languages for that matter. Arguments can be passed back and forth across calls, provided that they represent primitive data types that both languages recognize, and assuming that the Scripting Framework converts them appropriately.

### Синтаксис

workstation_name = script.invoke(Array(), Array(), Array())

opSysName = script.invoke(Array(), in_outs, Array()) ' in_out — масив

file_len = script.invoke(Array(systemFilePath), Array(), Array())

normalizedPath = script.invoke(Array(systemFilePath), Array(), Array())

### Приклади вкладених сценаріїв

Показані внизу процедури ComputerName і GetFilelen звертаються до відповідних обробників Python шляхом згаданих функцій GetPythonScript. Обробка винятків не деталізована.

             Option Explicit
             Option Compatible ' Властивості підтримуються

             Private scr As Object ' com.sun.star.script.provider.XScript

             Private Property Get ComputerName As String
                 '''Назва робочої станції'''
                 scr = GetPythonScript("Platform.py$computer_name", "document")
                 ComputerName = scr.invoke(Array(), Array(), Array())
             End Property ' ComputerName

             Private Function GetFilelen(systemFilePath As String) As Currency
                 '''File size in bytes'''
                 scr = GetPythonScript("Os/Path.py$get_size", Script.ISEMBEDDED)
                 GetFilelen = scr.invoke(Array(systemFilePath), Array(), Array(),)
             End Function ' GetFilelen

             Private Type _SCRIPT_LOCATION
                 ISEMBEDDED As String ' document script
                 ISPERSONAL As String ' user script
                 ISSHARED As String ' LibreOffice macro
             End Type ' _SCRIPT_LOCATION

             Public Function Script() As Object ' Text enumeration
                 Static enums As _SCRIPT_LOCATION : With enums
                 If .ISEMBEDDED = "" Then
                     .ISEMBEDDED = "document" ' document script
                     .ISPERSONAL = "user" ' user scripts
                     .ISSHARED = "share" ' LibreOffice macro
                 End If : End With ' enums
                 Script = enums
             End Function ' Script

Two different Python modules are called. They can either be embedded in the current document, either be stored on the file system. Argument type checking is skipped for clarity:

- Platform.py

             # -*- coding: utf-8 -*-
             from __future__ import unicode_literals

             import platform

             def computer_name() -> str:
                 return platform.node()

             def OSname() -> str:
                 return platform.system()

- Os/Path.py

             # -*- coding: utf-8 -*-
             from __future__ import unicode_literals

             import os.path

             def get_size(systemFilePath: str) -> str:
                 return str(os.path.getsize(systemFilePath))

             def normalyze(systemPath: str) -> str:
                 return os.path.normpath(systemPath)

### Personal or Shared Scripts Examples

The calling mechanism for personal or shared Python scripts is identical to that of embedded scripts. Library names are mapped to folders. Computing LibreOffice user profile and shared modules system file paths can be performed as detailed in Getting session information. Below OSName, HelloWorld and NormalizePath routines are calling their Python counterparts, using aforementioned GetPythonScript function. Exception handling is not detailed.

             Option Explicit
             Option Compatible ' Properties are supported

             Private scr As Object ' com.sun.star.script.provider.XScript

             Private Property Get OSName As String
                 '''Platform name as "Linux", "Darwin" or "Windows"'''
                 scr = GetPythonScript("Platform.py$OSname", Script.ISPERSONAL)
                 OSName = scr.invoke(Array(), Array(), Array())
             End Property ' OSName

             Private Sub HelloWorld()
                 '''LibreOffice Python shared sample'''
                 scr = GetPythonScript("HelloWorld.py$HelloWorldPython", Script.ISSHARED)
                 scr.invoke(Array(), Array(), Array(),)
             End Sub ' HelloWorld

             Public Function NormalizePath(systemFilePath As String) As String
                 '''Strip superfluous '\..' in path'''
                 scr = GetPythonScript("Os/Path.py$normalyze", "user")
                 NormalizePath = scr.invoke(Array(systemFilePath), Array(), Array())
             End Function ' NormalizePath

## Python standard modules

LibreOffice embedded Python contains many standard libraries to benefit from. They bear a rich feature set, such as but not limited to:

- argparse Parser for command-line options, arguments and sub-commands

- cmath Mathematical functions for complex numbers

- csv CSV files reading and writing

- datetime Genuine date and time types

- json JSON encoder and decoder

- math Mathematical functions

- re Regular expression operations

- socket Low-level networking interface

- sys System-specific parameters and functions

- unittest and trace Unit testing framework and Track Python execution

- xml.etree.ElementTree ElementTree XML API

Пов'язані теми

Calling Basic Macros from Python

LibreOffice Basic Help

Довідка щодо сценаріїв на LibreOffice Python

Будь ласка, підтримайте нас!